Softwaredesign: Beispiel: XML-Strukturbaum als Kompositum: Haskell Spezifikation

module XMLSyntaxTree
where
import Prelude hiding (lookup, map)
import qualified Prelude as P
import Map
data XMLTree    = PlainText     Text
                | Comment       Comment
                | CharRef       Unicode
                | EntityRef     String
                | SimpleElem    Tag
                | CompoundElem  Tag Content
type Content    = [XMLTree]
data Tag        = Tag ElemName  Attributes
type Attributes = Map AttrName  AttrValue
-- alias names
type Text       = String
type Comment    = String
type ElemName   = String
type AttrName   = String
type AttrValue  = String
type Unicode    = Int   -- or perhaps Char ?
-- questions
--
-- posible simplifications?
-- entity- or char references in attributes?
-- processing instructions?
-- ------------------------------------------------------------
--
-- one processing method
toString                :: XMLTree -> String
toString (PlainText t)  = t
toString (Comment c)    = "<!--" ++ c ++ "-->"
toString (CharRef r)    = "&#" ++ show r ++ ";"
toString (EntityRef e)  = "&" ++ e ++ ";"
toString (SimpleElem t) = stagToString t
toString (CompoundElem t c)
                        = ctagToString t c
stagToString            :: Tag -> String
stagToString (Tag n al) = "<" ++ n ++ attrToString al ++ "/>"
ctagToString            :: Tag -> Content -> String
ctagToString (Tag n al) cont
                        = "<" ++ n ++ attrToString al ++ ">" ++
                          concatMap toString cont ++
                          "</" ++ n ++ ">"
attrToString            :: Attributes -> String
attrToString al
    = foldWithKey aToString "" al
    where
    aToString k a rest = " " ++ k ++ "=\"" ++ a ++ "\"" ++ rest
-- ------------------------------------------------------------
--
-- select the plain text of a document
toText                  :: XMLTree -> String
toText (PlainText t)    = t
toText (Comment c)      = ""
toText (CharRef r)      = [toEnum r]
toText (EntityRef e)    = "&" ++ e ++ ";"
toText (SimpleElem t)   = ""
toText (CompoundElem t c)
                        = concatMap toText c
Beispiel: XML-Strukturbaum als Kompositum: Haskell Spezifikation

Das Datenmodell als Abstrakte Syntax in Haskell Notation

Vereinfachungen und Erweiterungen
